gitlab-ci: add links to CDash as annotations

.gitlab/artifacts.yml

@@ -4,6 +4,9 @@
   artifacts:
     expire_in: 1d
     when: always
+    reports:
+      annotations:
+        - build/annotations.json
     paths:
       # The artifacts of the build.
       # Generated headers.
@@ -17,3 +20,4 @@
       - build/Testing/
       # CDash files.
       - build/DartConfiguration.tcl
+      - build/cdash-build-id

.gitlab/ci/ctest_annotation.cmake

+function (ctest_annotation_report file)
+  set(label "")
+
+  if (EXISTS "${file}")
+    file(READ "${file}" json)
+  else ()
+    set(json "{\"CDash\": []}")
+  endif ()
+
+  foreach (arg IN LISTS ARGN)
+    if (NOT label)
+      set(label "${arg}")
+      continue ()
+    endif ()
+
+    set(item "{\"external_link\":{\"label\":\"${label}\",\"url\":\"${arg}\"}}")
+    set(label "")
+
+    string(JSON length LENGTH "${json}" "CDash")
+    string(JSON json SET "${json}" "CDash" "${length}" "${item}")
+  endforeach ()
+
+  file(WRITE "${file}" "${json}")
+endfunction ()
+
+if (NOT DEFINED build_id)
+  include("${CTEST_BINARY_DIRECTORY}/cdash-build-id" OPTIONAL)
+endif ()
+
+function (store_build_id build_id)
+  file(WRITE "${CTEST_BINARY_DIRECTORY}/cdash-build-id"
+    "set(build_id \"${build_id}\")\n")
+endfunction ()

.gitlab/ci/ctest_build.cmake

@@ -27,6 +27,14 @@ ctest_build(
   RETURN_VALUE build_result)
 ctest_submit(PARTS Build)
 
+include("${CMAKE_CURRENT_LIST_DIR}/ctest_annotation.cmake")
+if (DEFINED build_id)
+  ctest_annotation_report("${CTEST_BINARY_DIRECTORY}/annotations.json"
+    "Build Errors (${num_errors})" "https://open.cdash.org/viewBuildError.php?buildid=${build_id}"
+    "Build Warnings (${num_warnings})" "https://open.cdash.org/viewBuildError.php?type=1&buildid=${build_id}"
+  )
+endif ()
+
 if (build_result)
   message(FATAL_ERROR
     "Failed to build")

.gitlab/ci/ctest_configure.cmake

@@ -24,7 +24,19 @@ ctest_read_custom_files("${CTEST_BINARY_DIRECTORY}")
 
 # We can now submit because we've configured. This is a cmb-superbuild-ism.
 ctest_submit(PARTS Update)
-ctest_submit(PARTS Configure)
+ctest_submit(
+  PARTS Configure
+  BUILD_ID build_id)
+
+include("${CMAKE_CURRENT_LIST_DIR}/ctest_annotation.cmake")
+if (DEFINED build_id)
+  ctest_annotation_report("${CTEST_BINARY_DIRECTORY}/annotations.json"
+    "Build Summary" "https://open.cdash.org/build/${build_id}"
+    "Update" "https://open.cdash.org/build/${build_id}/update"
+    "Configure" "https://open.cdash.org/build/${build_id}/configure"
+  )
+  store_build_id("${build_id}")
+endif ()
 
 if (configure_result)
   message(FATAL_ERROR

.gitlab/ci/ctest_memcheck.cmake

@@ -28,6 +28,13 @@ ctest_memcheck(
   DEFECT_COUNT defects)
 ctest_submit(PARTS Memcheck)
 
+include("${CMAKE_CURRENT_LIST_DIR}/ctest_annotation.cmake")
+if (DEFINED build_id)
+  ctest_annotation_report("${CTEST_BINARY_DIRECTORY}/annotations.json"
+    "Defects (${defects})" "https://open.cdash.org/viewDynamicAnalysis.php?buildid=${build_id}"
+  )
+endif ()
+
 if (test_result)
   message(FATAL_ERROR
     "Failed to test")

.gitlab/ci/ctest_test.cmake

@@ -24,6 +24,17 @@ ctest_test(
   EXCLUDE "${test_exclusions}")
 ctest_submit(PARTS Test)
 
+include("${CMAKE_CURRENT_LIST_DIR}/ctest_annotation.cmake")
+if (DEFINED build_id)
+  ctest_annotation_report("${CTEST_BINARY_DIRECTORY}/annotations.json"
+    "Build Summary" "https://open.cdash.org/build/${build_id}"
+    "All Tests"     "https://open.cdash.org/viewTest.php?buildid=${build_id}"
+    "Test Failures" "https://open.cdash.org/viewTest.php?onlyfailed&buildid=${build_id}"
+    "Tests Not Run" "https://open.cdash.org/viewTest.php?onlynotrun&buildid=${build_id}"
+    "Test Passes"   "https://open.cdash.org/viewTest.php?onlypassed&buildid=${build_id}"
+  )
+endif ()
+
 if (test_result)
   message(FATAL_ERROR
     "Failed to test")