make add_test smart enough to run tests on DLL platforms

This is related to #24129 and #25684

To get my tests to run on Windows, I need the following boilerplate; CMake should take care of that for me.

    add_test(NAME ${test_target}
      COMMAND ${test_target})

    # When $ENV{PATH} is interpreted as a list on Windows, trailing backslashes in elements
    # (e.g. "C:\path\to\foo\;C:\another\path\...") will end up causing semicolons to be escaped.
    string(REPLACE "\\" "/" path "$ENV{PATH}")

    # Escape the semicolons when forming the environment setting.  As explained in
    # https://stackoverflow.com/a/59866840/125349, “this is not the last place the list will be used
    # (and interpreted by CMake). [It] is then used to populate CTestTestfile.cmake, which is later
    # read by CTest to setup your test environment.”
    set_tests_properties(${test_target}
      PROPERTIES ENVIRONMENT "PATH=$<JOIN:$<TARGET_RUNTIME_DLL_DIRS:${test_target}>;${path},\\;>")

mentioned in issue #24129

mentioned in issue #25684

changed the description

An workaround may by to build all DLL in the central bin directory as all executables:

On TopLevelProject add

set(stageDir ${CMAKE_CURRENT_BINARY_DIR})
include(GNUInstallDirs)

if(NOT CMAKE_RUNTIME_OUTPUT_DIRECTORY)
	set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${stageDir}/${CMAKE_INSTALL_BINDIR})
endif()
if(NOT CMAKE_LIBRARY_OUTPUT_DIRECTORY)
	set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${stageDir}/${CMAKE_INSTALL_LIBDIR})
endif()
if(NOT CMAKE_ARCHIVE_OUTPUT_DIRECTORY)
	set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${stageDir}/${CMAKE_INSTALL_LIBDIR})
endif()

``

That works for in-project target DLLs, but is insufficient if you need DLLs from outside the project.

User code can be simplified without need to escape like the minimal example:

add_executable(mytest mytest.c)

add_test(NAME mytest COMMAND mytest)

set_property(TEST mytest
PROPERTY ENVIRONMENT_MODIFICATION "PATH=path_list_append:$<TARGET_RUNTIME_DLL_DIRS:mytest>")

set_property(TEST mytest
PROPERTY ENVIRONMENT_MODIFICATION "PATH=path_list_append:$<TARGET_RUNTIME_DLL_DIRS:mytest>")

This looks wrong:

• you want to APPEND to the ENVIRONMENT_MODIFICATION property
• I suspect this will end up adding only the first path and the second-and-future-paths will be interpreted as items in the ENVIRONMENT_MODIFICATION property (since ; is not escaped here)

Ok yes I think you're right. My example had only one dll on one path. This breaks with more than one dll path.

I think you need something like:

set(dll_dirs "$<TARGET_RUNTIME_DLL_DIRS:mytest>")
set(is_empty "$<STREQUAL:${dll_dirs},>")
set(env_op "PATH=path_list_append:"
set_property(TEST mytest APPEND
  PROPERTY
    ENVIRONMENT_MODIFICATION
      "$<$<NOT:${is_empty}>:${env_op}$<JOIN:${dll_dirs},$<SEMICOLON>${env_op}>>")