nvidiaindex: add project

CMakeLists.txt

@@ -128,6 +128,11 @@ function (superbuild_find_projects var)
       pywin32)
   endif ()
 
+  if (WIN32 OR (UNIX AND NOT APPLE))
+    list(APPEND projects
+      nvidiaindex)
+  endif ()
+
   set("${var}"
     ${projects}
     PARENT_SCOPE)

projects/nvidiaindex.cmake

+if (APPLE)
+  message(FATAL_ERROR
+    "NVIDIA IndeX is not supported on macOS.")
+endif ()
+
+if (superbuild_build_phase AND "x${CMAKE_CXX_COMPILER_ID}" STREQUAL "xMSVC")
+  if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "18.0" OR
+      NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "19.0")
+    message(FATAL_ERROR
+      "NVIDIA IndeX only provides libraries for MSVC 2013.")
+  endif ()
+endif ()
+
+superbuild_add_project(nvidiaindex
+  CONFIGURE_COMMAND
+    ""
+  BUILD_COMMAND
+    ""
+  INSTALL_COMMAND
+    "${CMAKE_COMMAND}"
+      -Dsource_dir:PATH=<SOURCE_DIR>
+      -Dinstall_dir:PATH=<INSTALL_DIR>
+      -P "${CMAKE_CURRENT_LIST_DIR}/scripts/nvidiaindex.install.cmake")

projects/scripts/nvidiaindex.install.cmake

+if (WIN32)
+  set(dir "bin")
+else ()
+  set(dir "lib")
+endif ()
+
+file(GLOB files "${source_dir}/lib/*")
+file(INSTALL ${files}
+  DESTINATION "${install_dir}/${dir}")
+
+# Make a fake CUDA library. The installer will skip it, but one needs to be
+# found for the fixup_bundle scripts.
+if (WIN32)
+  file(WRITE "${install_dir}/${dir}/nvcuda.dll" "")
+else ()
+  file(WRITE "${install_dir}/${dir}/libcuda.so.1" "")
+endif ()

versions.cmake

@@ -126,3 +126,14 @@ superbuild_set_revision(boxlib
 superbuild_set_revision(las
   URL     "https://www.paraview.org/files/dependencies/libLAS-1.8.1.tar.bz2"
   URL_MD5 2e6a975dafdf57f59a385ccb87eb5919)
+
+set(nvidiaindex_version "2.1.20180215")
+if (WIN32)
+  superbuild_set_revision(nvidiaindex
+    URL     "http://www.paraview.org/files/dependencies/nvidia-index-libs-${nvidiaindex_version}-vs2013-x64.tar.bz2"
+    URL_MD5 11bc04708dd97c8a41eb81b92b1b60d8)
+elseif (UNIX AND NOT APPLE)
+  superbuild_set_revision(nvidiaindex
+    URL     "http://www.paraview.org/files/dependencies/nvidia-index-libs-${nvidiaindex_version}-linux.tar.bz2"
+    URL_MD5 617908b181c27bea59d0817ae29fc8f3)
+endif ()