Refactored testing.

Instead of testing nightly binaries from the website, we now test
binaries generated by the superbuild itself.

CMakeLists.txt

@@ -325,25 +325,7 @@ if (paraview_ENABLED)
   include(paraview.bundle OPTIONAL)
 endif()
 
-option(NIGHTLY_BINARY_TESTING "Run Nightly-Binary ParaView Testing" OFF)
-
-# Create this cache option only if nightly binary testing is enabled,
-# but in that case, you will still have to explicitly turn it on.
-cmake_dependent_option(ENABLE_REMOTE_PVWEB_TEST
-  "Whether or not to include a test of remote pvweb instances" OFF
-  "NIGHTLY_BINARY_TESTING" OFF)
-set(REMOTE_PVWEB_VISUALIZER_URLS
-  http://pvw-test.kitware.com/sbtest
-  http://pvw.kitware.com/sbtest
-  http://paraviewweb.kitware.com/sbtest
-  CACHE STRING "A list of urls against which to run a simple Web Visualizer test.")
-set(REMOTE_PVWEB_TEST_BROWSER
-  firefox
-  CACHE STRING "Which browser to use during testing, either chrome or firefox")
-mark_as_advanced(ENABLE_REMOTE_PVWEB_TEST REMOTE_PVWEB_VISUALIZER_URLS REMOTE_PVWEB_TEST_BROWSER)
-if (NIGHTLY_BINARY_TESTING)
-  add_subdirectory(tests)
-endif()
+add_subdirectory(Testing)
 
 #------------------------------------------------------------------------------
 # Test to check install tree for paraviewsdk

Testing/CMakeLists.txt

+include(CMakeDependentOption)
+
+cmake_dependent_option(TEST_REMOTE_PARAVIEW_WEB
+  "When enabled, tests a live instance of ParaViewWeb." OFF
+  BUILD_TESTING OFF)
+#cmake_dependent_option(TEST_NIGHTLY_BINARIES
+#  "When enabled, tests are run on binaries downloaded from the specified URL rather than generated binaries" OFF
+#  BUILD_TESTING OFF)
+
+mark_as_advanced(TEST_REMOTE_PARAVIEW_WEB TEST_NIGHTLY_BINARIES)
+
+if (NOT BUILD_TESTING)
+  return()
+endif()
+
+set(REMOTE_PVWEB_VISUALIZER_URLS
+  http://pvw-test.kitware.com/sbtest
+  http://pvw.kitware.com/sbtest
+  http://paraviewweb.kitware.com/sbtest
+  CACHE STRING "A list of urls against which to run a simple Web Visualizer test.")
+set(REMOTE_PVWEB_TEST_BROWSER firefox
+  CACHE STRING "Which browser to use during testing, either chrome or firefox")
+mark_as_advanced(REMOTE_PVWEB_VISUALIZER_URLS REMOTE_PVWEB_TEST_BROWSER)
+
+include(${CMAKE_CURRENT_SOURCE_DIR}/tests.cmake)

Testing/PrepareBinaries.cmake

+# Prepares binaries for testing.
+# BINARY_DIRECTORY : Directory where the binary tar balls/zip/dmg etc are
+#                    present.
+# OUTPUT_DIRECTORY : Directory under which the paraview package must be
+# unravelled.
+# GLOB_PATTERN     : File pattern to glob for when locating the package file.
+
+# Remove the output directory to begin with.
+file(REMOVE_RECURSE "${OUTPUT_DIRECTORY}")
+
+file(MAKE_DIRECTORY "${OUTPUT_DIRECTORY}")
+
+# Find the package.
+file(GLOB files "${BINARY_DIRECTORY}/${GLOB_PATTERN}")
+
+list(LENGTH files files_length)
+if(files_length EQUAL 0)
+  message(FATAL_ERROR "Failed to locate package file using '${BINARY_DIRECTORY}/${GLOB_PATTERN}'")
+elseif(files_length GREATER 1)
+  message(FATAL_ERROR "Multiple package files found using '${BINARY_DIRECTORY}/${GLOB_PATTERN}':\n${files}")
+endif()
+
+message("Using package '${files}'")
+set(file "${files}")
+get_filename_component(file_ext "${file}" EXT)
+string(TOLOWER file_ext "${file_ext}")
+if(file_ext MATCHES "(\\.|=)(7z|tar\\.bz2|tar\\.gz|tar\\.xz|tbz2|tgz|txz|zip)$")
+  # This works for Windows and Linux.
+  file(MAKE_DIRECTORY "${OUTPUT_DIRECTORY}/__Extract__")
+  execute_process(
+    COMMAND ${CMAKE_COMMAND} -E tar xfz ${file}
+    WORKING_DIRECTORY ${OUTPUT_DIRECTORY}/__Extract__
+    OUTPUT_VARIABLE ov
+    ERROR_VARIABLE ov
+    RESULT_VARIABLE rv)
+  if(rv)
+    message(FATAL_ERROR
+      "Failed to extract the package. Output/Error messages are:
+=======================================================
+${ov}
+=======================================================\n")
+  endif()
+
+  # Strip empty directories and move the root to ${OUTPUT}.
+  file(GLOB contents "${OUTPUT_DIRECTORY}/__Extract__/*")
+  list(LENGTH contents contents_length)
+  if(NOT contents_length EQUAL 1 OR NOT IS_DIRECTORY "${contents}")
+    set(contents "${OUTPUT_DIRECTORY}/__Extract__")
+  endif()
+  file(RENAME "${contents}" "${OUTPUT_DIRECTORY}/../__Package__")
+  file(REMOVE_RECURSE "${OUTPUT_DIRECTORY}")
+  file(MAKE_DIRECTORY "${OUTPUT_DIRECTORY}")
+  file(RENAME "${OUTPUT_DIRECTORY}/../__Package__" "${OUTPUT_DIRECTORY}")
+  message("Package `installed` under '${OUTPUT_DIRECTORY}'")
+
+elseif(file_ext MATCHES "\\.dmg$")
+  execute_process(
+    COMMAND /bin/sh -c "yes | hdiutil attach -mountpoint ${OUTPUT_DIRECTORY}/__Mount__ ${file}"
+    RESULT_VARIABLE rv
+    OUTPUT_VARIABLE ov
+    ERROR_VARIABLE ov)
+  if (rv)
+    message(FATAL_ERROR "Failed to mount volume '${file}'!!! Output/Error messages are:
+=======================================================
+${ov}
+=======================================================\n")
+  endif()
+  message("Mounted volume as '${OUTPUT_DIRECTORY}/__Mount__'")
+
+  # Find the app to copy.
+  file(GLOB volume_contents "${OUTPUT_DIRECTORY}/__Mount__/*.app")
+  foreach(file IN LISTS volume_contents)
+    get_filename_component(appname "${file}" NAME)
+    message("Copying '${appname}'")
+    execute_process(
+      COMMAND ${CMAKE_COMMAND} -E copy_directory
+              "${file}"
+              "${OUTPUT_DIRECTORY}/__Extract__/${appname}"
+      RESULT_VARIABLE rv
+      OUTPUT_VARIABLE ov
+      ERROR_VARIABLE ov)
+    if (rv)
+      message(FATAL_ERROR "Failed to copy from volume to directory!!! Output/Error message are:
+=======================================================
+${ov}
+=======================================================\n")
+    endif()
+  endforeach()
+
+  # unmount volume
+  execute_process(COMMAND hdiutil detach "${OUTPUT_DIRECTORY}/__Mount__")
+
+  # Now put the contents in __Extract__ to the same location as ${OUTPUT_DIRECTORY}}
+  file(RENAME "${OUTPUT_DIRECTORY}/__Extract__" "${OUTPUT_DIRECTORY}/../__Package__")
+  file(REMOVE_RECURSE "${OUTPUT_DIRECTORY}")
+  file(MAKE_DIRECTORY "${OUTPUT_DIRECTORY}")
+  file(RENAME "${OUTPUT_DIRECTORY}/../__Package__" "${OUTPUT_DIRECTORY}")
+  message("Package `installed` under '${OUTPUT_DIRECTORY}'")
+endif()

tests/tests.cmake → Testing/tests.cmake

 # This needs the following variables to be set.
-#   PV_NIGHTLY_PARAVIEW
-#   PV_NIGHTLY_PVPYTHON
-#   PV_NIGHTLY_PVSERVER
-#   PV_NIGHTLY_PVBATCH
-#   PV_NIGHTLY_PVBLOT
-#   PV_NIGHTLY_PVDATASERVER
-#   PV_NIGHTLY_PVRENDERSERVER
+#   PARAVIEW_EXECUTABLE
+#   PVPYTHON_EXECUTABLE
+#   PVSERVER_EXECUTABLE
+#   PVBATCH_EXECUTABLE
+
+#------------------------------------------------------------------------------
+set (INSTALLED_PACKAGE_ROOT "${CMAKE_CURRENT_BINARY_DIR}/InstalledPackageRoot")
+
+if(WIN32)
+  set (glob_pattern "ParaView*.zip")
+  set (package_generation_test "GenerateParaViewPackage-ZIP")
+elseif(APPLE)
+  set (glob_pattern "ParaView*.dmg")
+  set (package_generation_test "GenerateParaViewPackage")
+else()
+  set (glob_pattern "ParaView*.tar.gz")
+  set (package_generation_test "GenerateParaViewPackage")
+  set (PARAVIEW_EXECUTABLE "${INSTALLED_PACKAGE_ROOT}/bin/paraview")
+  set (PVPYTHON_EXECUTABLE "${INSTALLED_PACKAGE_ROOT}/bin/pvpython")
+  set (PVSERVER_EXECUTABLE "${INSTALLED_PACKAGE_ROOT}/bin/pvserver")
+  set (PVBATCH_EXECUTABLE "${INSTALLED_PACKAGE_ROOT}/bin/pvbatch")
+endif()
+
+add_test(NAME PrepareBinariesForTesting
+  COMMAND ${CMAKE_COMMAND}
+          -DBINARY_DIRECTORY:PATH=${ParaViewSuperBuild_BINARY_DIR}
+          -DOUTPUT_DIRECTORY:PATH=${INSTALLED_PACKAGE_ROOT}
+          -DGLOB_PATTERN:STRING=${glob_pattern}
+          -P ${CMAKE_CURRENT_LIST_DIR}/PrepareBinaries.cmake
+          )
+set_tests_properties(PrepareBinariesForTesting PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS ${package_generation_test})
 
 #------------------------------------------------------------------------------
 # Simple test to launch the application and load all plugins.
 add_test(NAME TestUI
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+         COMMAND "${PARAVIEW_EXECUTABLE}"
                  "-dr"
                  "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
                  "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestUI.xml"
                  "--exit")
-set_tests_properties(TestUI PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(TestUI PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 #------------------------------------------------------------------------------
 # Simple test of a public, automatically deployed version of paraviewweb.  If
@@ -40,96 +66,105 @@ endif()
 if (NOT WIN32)
   # we don't package ParaViewWeb on Windows anymore.
   add_test(NAME Test-pvweb
-           COMMAND "${PV_NIGHTLY_PVPYTHON}"
+           COMMAND "${PVPYTHON_EXECUTABLE}"
                    "${CMAKE_CURRENT_SOURCE_DIR}/basic_paraviewweb.py")
-  set_tests_properties(Test-pvweb PROPERTIES LABELS "PARAVIEW")
+  set_tests_properties(Test-pvweb PROPERTIES
+                       LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 endif()
 #------------------------------------------------------------------------------
 # Simple test to test pvpython/pvbatch.
 add_test(NAME Test-pvpython
-         COMMAND "${PV_NIGHTLY_PVPYTHON}"
+         COMMAND "${PVPYTHON_EXECUTABLE}"
                  "${CMAKE_CURRENT_SOURCE_DIR}/basic_python.py")
-set_tests_properties(Test-pvpython PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(Test-pvpython PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 if (NOT WIN32)
   # Windows MPI has issues with pvbatch.
   add_test(NAME Test-pvbatch
-           COMMAND "${PV_NIGHTLY_PVBATCH}"
+           COMMAND "${PVBATCH_EXECUTABLE}"
                    "${CMAKE_CURRENT_SOURCE_DIR}/basic_python.py")
-  set_tests_properties(Test-pvbatch PROPERTIES LABELS "PARAVIEW")
+  set_tests_properties(Test-pvbatch PROPERTIES
+                       LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 endif()
 
 # Test to load various data files to ensure reader support.
 #----------------------------------------------------------------------------
 add_test(NAME TestData-csg.silo
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+         COMMAND "${PARAVIEW_EXECUTABLE}"
                  "-dr"
                  "--data=${CMAKE_CURRENT_SOURCE_DIR}/Data/csg.silo"
                  "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
                  "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestData-cs_silo.xml"
                  "--exit")
-set_tests_properties(TestData-csg.silo PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(TestData-csg.silo PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 #----------------------------------------------------------------------------
 add_test(NAME TestData-5blocks.cgns
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+         COMMAND "${PARAVIEW_EXECUTABLE}"
                  "-dr"
                  "--data=${CMAKE_CURRENT_SOURCE_DIR}/Data/5blocks.cgns"
                  "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
                  "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestData-5blocks_cgns.xml"
                  "--exit")
-set_tests_properties(TestData-5blocks.cgns PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(TestData-5blocks.cgns PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 #----------------------------------------------------------------------------
 # Disabling this test for now since the Data file is too big. We probably need
 # to add support for Data repository similar to ParaView/VTK soon.
 #add_test(NAME TestData-Scenario1_p1.xmf
-#         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+#         COMMAND "${PARAVIEW_EXECUTABLE}"
 #                 "-dr"
 #                 "--data=${CMAKE_CURRENT_SOURCE_DIR}/Data/Scenario1_p1.xmf"
 #                 "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
 #                 "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestData.xml"
 #                 "--exit")
-#set_tests_properties(TestData-Scenario1_p1.xmf PROPERTIES LABELS "PARAVIEW")
+#set_tests_properties(TestData-Scenario1_p1.xmf PROPERTIES
+#         LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
+
+
 
 #----------------------------------------------------------------------------
 add_test(NAME TestMatplotlib
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+         COMMAND "${PARAVIEW_EXECUTABLE}"
                  "-dr"
                  "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
                  "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestMatplotlib.xml"
                  "--test-baseline=${CMAKE_CURRENT_SOURCE_DIR}/Baselines/Superbuild-TestMatplotlib.png"
                  "--exit")
-set_tests_properties(TestMatplotlib PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(TestMatplotlib PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 #----------------------------------------------------------------------------
 add_test(NAME TestPythonView
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+         COMMAND "${PARAVIEW_EXECUTABLE}"
                  "-dr"
                  "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
                  "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestPythonView.xml"
                  "--test-baseline=${CMAKE_CURRENT_SOURCE_DIR}/Baselines/TestPythonView.png"
                  "--exit")
-set_tests_properties(TestPythonView PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(TestPythonView PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 #----------------------------------------------------------------------------
 add_test(NAME TestFindData
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
+         COMMAND "${PARAVIEW_EXECUTABLE}"
                  "-dr"
                  "--test-directory=${SuperBuild_BINARY_DIR}/Testing/Temporary"
                  "--test-script=${CMAKE_CURRENT_SOURCE_DIR}/TestFindData.xml"
                  "--test-baseline=${CMAKE_CURRENT_SOURCE_DIR}/Baselines/Superbuild-TestFindData.png"
                  "--exit")
-set_tests_properties(TestFindData PROPERTIES LABELS "PARAVIEW")
+set_tests_properties(TestFindData PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
+
+#----------------------------------------------------------------------------
+add_test(NAME PrintVersionServer COMMAND "${PVSERVER_EXECUTABLE}" "--version")
+set_tests_properties(PrintVersionServer PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")
 
 #----------------------------------------------------------------------------
-add_test(NAME PrintVersionServer
-         COMMAND "${PV_NIGHTLY_PVSERVER}"
-                 "--version"
-        )
-set_tests_properties(PrintVersionServer PROPERTIES LABELS "PARAVIEW")
-add_test(NAME PrintVersionClient
-         COMMAND "${PV_NIGHTLY_PARAVIEW}"
-                 "--version"
-        )
-set_tests_properties(PrintVersionClient PROPERTIES LABELS "PARAVIEW")
+add_test(NAME PrintVersionClient COMMAND "${PARAVIEW_EXECUTABLE}" "--version")
+set_tests_properties(PrintVersionClient PROPERTIES
+                     LABELS "PARAVIEW" DEPENDS "PrepareBinariesForTesting")

tests/CMakeLists.txt

-# CMake script used to setup ParaView Nightly binary in order to test them
-#
-# The following variable need to be set by you:
-# - PV_NIGHTLY_SUFFIX : Suffix that should be tested on that given computer.
-#                       i.e.: glibc-2.3.6-NIGHTLY, glibc-2.15-NIGHTLY,
-#                             10.6-10.7-NIGHTLY, 10.8-NIGHTLY, 10.8-NoMPI-NIGHTLY
-#
-# The following variable will be set for you:
-# - PV_NIGHTLY_PARAVIEW : ParaView executable
-# - PV_NIGHTLY_PVPYTHON : pvpython executable
-# - PV_NIGHTLY_PVSERVER : pvserver executable
-# - PV_NIGHTLY_PVBATCH  : pvbatch executable
-# - PV_NIGHTLY_PVBLOT   : pvbatch executable
-# - PV_NIGHTLY_PVDATASERVER   : dataserver executable
-# - PV_NIGHTLY_PVRENDERSERVER : renderserver executable
-message(STATUS "Binary test-suite is enabled")
-
-#------------------------------------------------------------------------------
-# Method to download a remote file. Will raise fatal errors on failure.
-#   remoteurl:- url to download
-#   localfilename:- path to locate file that the downloaded file will be saved as.
-function(download remoteurl localfilename)
-  # Download the file(s).
-  file(DOWNLOAD "${remoteurl}"
-                "${localfilename}"
-                STATUS status
-                LOG log
-                SHOW_PROGRESS)
-  list(GET status 0 status_code)
-  list(GET status 1 status_string)
-  if(NOT status_code EQUAL 0)
-    message(FATAL_ERROR "error: downloading '${remoteurl}' failed
-    status_code: ${status_code}
-    status_string: ${status_string}
-    log: ${log}")
-  endif()
-endfunction()
-
-#------------------------------------------------------------------------------
-function(extract filename destination)
-  set(args "")
-  if(filename MATCHES "(\\.bz2|\\.tar\\.gz|\\.tgz|\\.zip)$")
-    set(args xfz)
-  elseif(filename MATCHES "\\.tar$")
-    set(args xf)
-  else()
-    # assume archive is already extracted.
-    return()
-  endif()
-endfunction()
-
-#------------------------------------------------------------------------------
-set(SUPERBUILD_DOWNLOAD_BASE_URL "http://www.paraview.org/files/nightly")
-set(PV_NIGHTLY_PARAVIEW "")
-set(PV_NIGHTLY_PVPYTHON "")
-set(PV_NIGHTLY_PVSERVER "")
-set(PV_NIGHTLY_PVBATCH  "")
-set(PV_NIGHTLY_PVBLOT   "")
-set(PV_NIGHTLY_PVDATASERVER   "")
-set(PV_NIGHTLY_PVRENDERSERVER "")
-
-if (64bit_build)
-  set (PARAVIEW_BUILD_ARCHITECTURE "64")
-else()
-  set (PARAVIEW_BUILD_ARCHITECTURE "32")
-endif()
-
-set (PV_NIGHTLY_SUFFIX "${PARAVIEW_BUILD_ARCHITECTURE}bit-NIGHTLY"
-     CACHE STRING "Suffix to use for binaries to download, e.g. 64bit-glibc-2.15-NIGHTLY")
-
-# ---------------------------------
-#             Linux
-# ---------------------------------
-
-if(UNIX AND NOT APPLE)
-    set(paraview_nightly_server_filename "ParaView-Linux-${PV_NIGHTLY_SUFFIX}.tar.gz")
-    ExternalProject_Add( Nightly-ParaView
-       URL "${SUPERBUILD_DOWNLOAD_BASE_URL}/${paraview_nightly_server_filename}"
-       SOURCE_DIR ${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly
-       BINARY_DIR ""
-       UPDATE_COMMAND ""
-       CONFIGURE_COMMAND ""
-       BUILD_COMMAND ""
-       INSTALL_COMMAND ""
-    )
-
-    # Setup Unix specific path
-    set(PV_NIGHTLY_PARAVIEW "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/paraview")
-    set(PV_NIGHTLY_PVPYTHON "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvpython")
-    set(PV_NIGHTLY_PVSERVER "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvserver")
-    set(PV_NIGHTLY_PVBATCH  "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvbatch")
-    set(PV_NIGHTLY_PVBLOT   "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvblot")
-    set(PV_NIGHTLY_PVDATASERVER   "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvdataserver")
-    set(PV_NIGHTLY_PVRENDERSERVER "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvrenderserver")
-
-endif()
-
-# ---------------------------------
-#             Mac
-# ---------------------------------
-
-if(APPLE)
-    set(paraview_nightly_server_filename "ParaView-Darwin-${PV_NIGHTLY_SUFFIX}.dmg")
-    set(paraview_nightly_filePath ${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/PVNightly.dmg)
-
-    if(NOT EXISTS ${paraview_nightly_filePath})
-       message("Downloading:  ${SUPERBUILD_DOWNLOAD_BASE_URL}/${paraview_nightly_server_filename}")
-       # Download
-       file(DOWNLOAD
-          ${SUPERBUILD_DOWNLOAD_BASE_URL}/${paraview_nightly_server_filename}
-          ${paraview_nightly_filePath}
-       )
-
-       # Mount DMG
-       execute_process(
-          COMMAND hdiutil attach ${paraview_nightly_filePath}
-          RESULT_VARIABLE MOUNT_EXIT_CODE
-          OUTPUT_VARIABLE output
-          ERROR_VARIABLE errors)
-
-       string(REPLACE "\t" ";" output_list "${output}")
-       list(REVERSE output_list)
-       list(GET output_list 0 arg)
-       string(STRIP "${arg}" DIRECTORY_PATH)
-       list(GET output_list 2 arg)
-       string(STRIP "${arg}" DMG_MOUNT_PATH)
-
-       # Copy application and unmount
-       if (${MOUNT_EXIT_CODE} EQUAL 0)
-          execute_process(
-             COMMAND ${CMAKE_COMMAND} -E copy_directory "${DIRECTORY_PATH}/paraview.app" "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly"
-          )
-          execute_process(
-             COMMAND hdiutil detach ${DMG_MOUNT_PATH}
-             OUTPUT_VARIABLE output
-             ERROR_VARIABLE errors
-          )
-       else()
-          message("We were unable to mount the file ${paraview_superbuild_filePath}")
-       endif()
-    endif()
-
-    # Setup Apple specific path
-    set(PV_NIGHTLY_PARAVIEW "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/MacOS/paraview")
-    set(PV_NIGHTLY_PVPYTHON "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/bin/pvpython")
-    set(PV_NIGHTLY_PVSERVER "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/bin/pvserver")
-    set(PV_NIGHTLY_PVBATCH  "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/bin/pvbatch")
-    set(PV_NIGHTLY_PVBLOT   "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/bin/pvblot")
-    set(PV_NIGHTLY_PVDATASERVER   "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/bin/pvdataserver")
-    set(PV_NIGHTLY_PVRENDERSERVER "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/Contents/bin/pvrenderserver")
-
-endif()
-
-# ---------------------------------
-#           Windows
-# ---------------------------------
-
-if(WIN32 OR WIN64)
-    set(paraview_nightly_server_filename "ParaView-Windows-${PV_NIGHTLY_SUFFIX}.zip")
-
-    ExternalProject_Add( Nightly-ParaView
-       URL "${SUPERBUILD_DOWNLOAD_BASE_URL}/${paraview_nightly_server_filename}"
-       SOURCE_DIR ${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly
-       BINARY_DIR ""
-       UPDATE_COMMAND ""
-       CONFIGURE_COMMAND ""
-       BUILD_COMMAND ""
-       INSTALL_COMMAND ""
-    )
-
-    # Setup Windows specific path
-    set(PV_NIGHTLY_PARAVIEW "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/paraview.exe")
-    set(PV_NIGHTLY_PVPYTHON "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvpython.exe")
-    set(PV_NIGHTLY_PVSERVER "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvserver.exe")
-    set(PV_NIGHTLY_PVBATCH  "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvbatch.exe")
-    set(PV_NIGHTLY_PVBLOT   "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvblot.exe")
-    set(PV_NIGHTLY_PVDATASERVER   "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvdataserver.exe")
-    set(PV_NIGHTLY_PVRENDERSERVER "${CMAKE_CURRENT_BINARY_DIR}/ParaViewNightly/bin/pvrenderserver.exe")
-
-endif()
-
-if (BUILD_TESTING)
-  include(${CMAKE_CURRENT_SOURCE_DIR}/tests.cmake)
-endif(BUILD_TESTING)