Working on brand new paraview-superbuild for linux binaries.

CMake/ParaViewModules.cmake

+include(ExternalProject)
+
+function(add_project name)
+  include("${name}")
+endfunction()

CMake/png.cmake

+
+ExternalProject_Add(
+  png
+  DEPENDS zlib
+  PREFIX png
+  URL "ftp://ftp.simplesystems.org/pub/libpng/png/src/libpng-1.5.7.tar.gz"
+  URL_MD5 944b56a84b65d94054cc73d7ff965de8
+  DOWNLOAD_DIR ${CMAKE_CURRENT_BINARY_DIR}/downloads
+  CMAKE_ARGS
+    -DCMAKE_INSTALL_PREFIX:PATH=${internal_install_root}
+    -DPNG_TESTS:BOOL=OFF
+    -DCMAKE_PREFIX_PATH=${internal_install_root}
+  )

CMake/python.cmake

+
+# FIXME: I'm not sure I was successful in making Python use the zlib we built
+# :(.
+set (old_ldflags $ENV{LDFLAGS})
+set (old_cppflags $ENV{CPPFLAGS})
+
+set (ENV{LDFLAGS} ${old_ldflags} -L${internal_install_root}/lib)
+set (ENV{CPPFLAGS} ${old_cppflags} -I${internal_install_root}/include)
+ExternalProject_Add(
+  python
+  DEPENDS zlib png
+  PREFIX python
+  URL "http://python.org/ftp/python/2.7.2/Python-2.7.2.tgz"
+  URL_MD5 "0ddfe265f1b3d0a8c2459f5bf66894c7"
+  DOWNLOAD_DIR ${CMAKE_CURRENT_BINARY_DIR}/downloads
+  CONFIGURE_COMMAND <SOURCE_DIR>/configure
+                    --prefix=${internal_install_root}
+                    --enable-unicode
+  )
+

CMake/zlib.cmake

+
+# zlib supports cmake. the only problem is that we need to remove the zconf.h
+# file.
+ExternalProject_Add(
+  zlib
+  PREFIX zlib
+  URL "http://zlib.net/zlib-1.2.5.tar.gz"
+  URL_MD5 c735eab2d659a96e5a594c9e8541ad63
+  DOWNLOAD_DIR ${CMAKE_CURRENT_BINARY_DIR}/downloads
+  # remove the zconf.g as a patch step.
+  PATCH_COMMAND cmake -E remove -f <SOURCE_DIR>/zconf.h
+  CMAKE_ARGS
+    -DCMAKE_INSTALL_PREFIX:PATH=${internal_install_root}
+    -DCMAKE_PREFIX_PATH=${internal_install_root}
+  )

CMakeLists.txt

+cmake_minimum_required(VERSION 2.8)
+project(ParaViewSuperBuild)
+set (CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/CMake")
+
+include (ParaViewModules)
+
+set (internal_install_root "${CMAKE_CURRENT_BINARY_DIR}/install")
+add_project(zlib)
+add_project(png)
+add_project(python)