
set(ace3p_python_tests)

if (SMTK_ENABLE_VTK_SUPPORT)
  list(APPEND ace3p_python_tests
    omega3p_test1
  )
endif()

set(smtk_pythonpath ${smtk_DIR}/${SMTK_PYTHONPATH})
if(NOT IS_ABSOLUTE ${smtk_pythonpath})
  get_filename_component(smtk_pythonpath
    ${PROJECT_BINARY_DIR}/${smtk_DIR}/${SMTK_PYTHON_MODULEDIR} ABSOLUTE)
endif()

set(pyenv
  ${PROJECT_BINARY_DIR}
  ${smtk_pythonpath}
  $ENV{PYTHONPATH})
if (WIN32)
  string(REPLACE ";" "\;" pyenv "${pyenv}")
else ()
  string(REPLACE ";" ":" pyenv "${pyenv}")
endif()

set(pathenv)
if (WIN32)
  set(pathenv
    ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
    $ENV{PATH})
  string(REPLACE ";" "\;" pathenv "${pathenv}")
endif()

foreach (test ${ace3p_python_tests})
  add_test(
    NAME ${test}_py
    COMMAND  "${PYTHON_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/${test}.py"
    --data-dir=${PROJECT_SOURCE_DIR}/data
    --temp-dir=${CMAKE_BINARY_DIR}/Testing/Temporary
    --src-dir=${CMAKE_SOURCE_DIR}
    )
    set_tests_properties("${test}_py"
    PROPERTIES
    ENVIRONMENT "PYTHONPATH=${pyenv}"
    LABELS "ACE3P Simulation"
    )
  if (pathenv)
    set_property(TEST "${test}_py" APPEND
      PROPERTY
        ENVIRONMENT "PATH=${pathenv}"
      )
  endif ()
endforeach()
