Commit 930827d4 authored by David Cole's avatar David Cole

ENH: First draft of add_external_project functionality. Tweaks, dashboard...

ENH: First draft of add_external_project functionality. Tweaks, dashboard fixing, more tests and documentation certain to follow as it gets used by others...
parent 7c244521
This diff is collapsed.
#
# Use 'cmake -Dremote=${url} -Dlocal=${filename} -Dtimeout=${seconds}
# -P DownloadFile.cmake' to call this script...
#
if(NOT DEFINED remote)
message(FATAL_ERROR "error: required variable 'remote' not defined...")
endif()
if(NOT DEFINED local)
message(FATAL_ERROR "error: required variable 'local' not defined...")
endif()
if(NOT DEFINED timeout)
set(timeout 30)
endif(NOT DEFINED timeout)
message(STATUS "info: downloading '${remote}'...")
file(DOWNLOAD "${remote}" "${local}" TIMEOUT ${timeout} STATUS status LOG log)
list(GET status 0 status_code)
list(GET status 1 status_string)
if(NOT status_code EQUAL 0)
message(FATAL_ERROR "error: download of '${remote}' failed
status_code: ${status_code}
status_string: ${status_string}
log: ${log}
")
endif()
message(STATUS "info: done downloading '${remote}'...")
repository='@repository@'
module='@module@'
tag='@tag@'
#
# Use 'cmake -Dfilename=${tar_or_tgz_file} -Dtmp=${tmp_directory} -Ddirectory=${final_directory}
# -P UntarFile.cmake' to call this script...
#
if(NOT DEFINED filename)
message(FATAL_ERROR "error: required variable 'filename' not defined...")
endif()
if(NOT DEFINED tmp)
message(FATAL_ERROR "error: required variable 'tmp' not defined...")
endif()
if(NOT DEFINED directory)
message(FATAL_ERROR "error: required variable 'directory' not defined...")
endif()
if(NOT DEFINED args)
if(filename MATCHES ".tar$")
set(args xf)
endif()
if(filename MATCHES ".tgz$")
set(args xfz)
endif()
if(filename MATCHES ".tar.gz$")
set(args xfz)
endif()
endif()
# Make file names absolute:
#
get_filename_component(filename "${filename}" ABSOLUTE)
get_filename_component(tmp "${tmp}" ABSOLUTE)
get_filename_component(directory "${directory}" ABSOLUTE)
# Prepare a space for untarring:
#
#message(STATUS "info: creating empty subdir of '${tmp}'...")
set(i 1)
while(EXISTS "${tmp}/untar${i}")
math(EXPR i "${i} + 1")
endwhile()
set(ut_dir "${tmp}/untar${i}")
file(MAKE_DIRECTORY "${ut_dir}")
# Untar it:
#
#message(STATUS "info: untarring '${filename}' in '${ut_dir}' with '${args}'...")
execute_process(COMMAND ${CMAKE_COMMAND} -E tar ${args} ${filename}
WORKING_DIRECTORY ${ut_dir}
RESULT_VARIABLE rv)
if(NOT rv EQUAL 0)
message(FATAL_ERROR "error: untar of '${filename}' failed")
endif()
# Analyze what came out of the tar file:
#
file(GLOB contents "${ut_dir}/*")
set(is_one_directory 0)
list(LENGTH contents n)
if(n EQUAL 1)
if(IS_DIRECTORY "${contents}")
set(is_one_directory 1)
endif()
endif()
# Copy "the one" directory to the final directory:
#
if(is_one_directory EQUAL 1)
#message(STATUS "info: (1) copying '${contents}' to '${directory}'...")
execute_process(COMMAND ${CMAKE_COMMAND} -E copy_directory "${contents}" "${directory}"
RESULT_VARIABLE rv)
else()
#message(STATUS "info: (more) copying '${ut_dir}' to '${directory}'...")
execute_process(COMMAND ${CMAKE_COMMAND} -E copy_directory "${ut_dir}" "${directory}"
RESULT_VARIABLE rv)
endif()
if(NOT rv EQUAL 0)
message(FATAL_ERROR "error: copy_directory failed after untar in '${ut_dir}'")
endif()
# Clean up:
#
file(REMOVE_RECURSE "${ut_dir}")
......@@ -510,6 +510,19 @@ ${CMake_BINARY_DIR}/bin/cmake -DVERSION=CVS -P ${CMake_SOURCE_DIR}/Utilities/Rel
)
LIST(APPEND TEST_BUILD_DIRS "${CMake_BINARY_DIR}/Tests/Environment")
ADD_TEST(ExternalProject ${CMAKE_CTEST_COMMAND}
--build-and-test
"${CMake_SOURCE_DIR}/Tests/ExternalProject"
"${CMake_BINARY_DIR}/Tests/ExternalProject"
--build-generator ${CMAKE_TEST_GENERATOR}
--build-project ExternalProjectTest
--build-makeprogram ${CMAKE_TEST_MAKEPROGRAM}
--build-exe-dir "${CMake_BINARY_DIR}/Tests/ExternalProject"
--force-new-ctest-process
--test-command ${CMAKE_CTEST_COMMAND} -VV
)
LIST(APPEND TEST_BUILD_DIRS "${CMake_BINARY_DIR}/Tests/ExternalProject")
# do each of the tutorial steps
FOREACH(STP RANGE 1 7)
ADD_TEST(TutorialStep${STP} ${CMAKE_CTEST_COMMAND}
......
cmake_minimum_required(VERSION 2.6)
project(ExternalProjectTest NONE)
include(AddExternalProject)
get_external_project_directories(base_dir build_dir downloads_dir install_dir
sentinels_dir source_dir tmp_dir)
set(prefix "${install_dir}")
# Local DIR:
#
set(proj TutorialStep5-Local)
add_external_project(${proj}
DIR "${CMAKE_CURRENT_SOURCE_DIR}/../Tutorial/Step5"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
)
# Local TAR:
#
set(proj TutorialStep1-LocalTAR)
add_external_project(${proj}
TAR "${CMAKE_CURRENT_SOURCE_DIR}/Step1.tar"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
set(proj TutorialStep1-LocalNoDirTAR)
add_external_project(${proj}
TAR "${CMAKE_CURRENT_SOURCE_DIR}/Step1NoDir.tar"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
# Local TGZ:
#
set(proj TutorialStep1-LocalTGZ)
add_external_project(${proj}
TGZ "${CMAKE_CURRENT_SOURCE_DIR}/Step1.tgz"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
set(proj TutorialStep1-LocalNoDirTGZ)
add_external_project(${proj}
TGZ "${CMAKE_CURRENT_SOURCE_DIR}/Step1.tgz"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
# Download TAR:
#
# TODO: Add a remote .tar file
# Download TGZ:
#
# TODO: Add a remote .tgz file
# Download CVS:
#
if(CVS_EXECUTABLE)
# CVS by date stamp:
#
set(proj KWStyle-20081201)
add_external_project(${proj}
CVS_REPOSITORY ":pserver:anoncvs@public.kitware.com:/cvsroot/KWStyle"
CVS_MODULE "KWStyle"
CVS_TAG "-D\;2008-12-01 01:00:00 UTC"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
)
# CVS by tag:
#
set(proj kwsys-from-CMake-2-6-2)
add_external_project(${proj}
CVS_REPOSITORY ":pserver:anonymous:cmake@www.cmake.org:/cvsroot/CMake"
CVS_MODULE "CMake/Source/kwsys"
CVS_TAG "-r\;CMake-2-6-2"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
# Live CVS / HEAD (no CVS_TAG):
#
set(proj TutorialStep1-CVSHEAD)
add_external_project(${proj}
CVS_REPOSITORY ":pserver:anonymous:cmake@www.cmake.org:/cvsroot/CMake"
CVS_MODULE "CMake/Tests/Tutorial/Step1"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
endif()
# Download SVN:
#
if(Subversion_SVN_EXECUTABLE)
# SVN by date stamp:
#
set(proj gdcm-md5-20081204)
add_external_project(${proj}
SVN_REPOSITORY "http://gdcm.svn.sourceforge.net/svnroot/gdcm/trunk/Utilities/gdcmmd5"
SVN_TAG "-r\;{2008-12-04 01:00:00 +0000}"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
)
# SVN by revision number:
#
set(proj gdcm-md5-r4824)
add_external_project(${proj}
SVN_REPOSITORY "http://gdcm.svn.sourceforge.net/svnroot/gdcm/trunk/Utilities/gdcmmd5"
SVN_TAG "-r\;4824"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
# Live SVN / trunk (no SVN_TAG):
#
set(proj gdcm-md5-SVNtrunk)
add_external_project(${proj}
SVN_REPOSITORY "http://gdcm.svn.sourceforge.net/svnroot/gdcm/trunk/Utilities/gdcmmd5"
CONFIGURE_ARGS "\"-DCMAKE_INSTALL_PREFIX:PATH=${prefix}\" -G \"${CMAKE_GENERATOR}\" \"${source_dir}/${proj}\""
INSTALL_COMMAND ""
)
endif()
# Test the testable built/installed products:
#
enable_testing()
# Use these as input to the KWStyle tests:
#
set(kwstyleXmlFile "${source_dir}/KWStyle-20081201/Testing/Data/0001-KWStyleConfiguration.kws.xml")
set(header "${install_dir}/include/TutorialConfig.h")
# Do at least a smoke test of a built executable from each
# project's build directory...
#
# BuildTree tests:
#
add_test(TutorialStep5-Local-BuildTreeTest
"${build_dir}/TutorialStep5-Local/Tutorial" 42)
add_test(TutorialStep1-LocalTAR-BuildTreeTest
"${build_dir}/TutorialStep1-LocalTAR/Tutorial" 36)
add_test(TutorialStep1-LocalNoDirTAR-BuildTreeTest
"${build_dir}/TutorialStep1-LocalNoDirTAR/Tutorial" 25)
add_test(TutorialStep1-LocalTGZ-BuildTreeTest
"${build_dir}/TutorialStep1-LocalTGZ/Tutorial" 16)
add_test(TutorialStep1-LocalNoDirTGZ-BuildTreeTest
"${build_dir}/TutorialStep1-LocalNoDirTGZ/Tutorial" 9)
if(CVS_EXECUTABLE)
add_test(KWStyle-20081201-BuildTreeTest
"${build_dir}/KWStyle-20081201/KWStyle" -xml "${kwstyleXmlFile}" "${header}")
add_test(kwsys-from-CMake-2-6-2-BuildTreeTest
"${build_dir}/kwsys-from-CMake-2-6-2/kwsysTestProcess" 1)
add_test(TutorialStep1-CVSHEAD-BuildTreeTest
"${build_dir}/TutorialStep1-LocalNoDirTGZ/Tutorial" 4)
endif()
if(Subversion_SVN_EXECUTABLE)
add_test(gdcm-md5-20081204-BuildTreeTest
"${build_dir}/gdcm-md5-20081204/md5main" --version)
add_test(gdcm-md5-r4824-BuildTreeTest
"${build_dir}/gdcm-md5-r4824/md5main" --version)
add_test(gdcm-md5-SVNtrunk-BuildTreeTest
"${build_dir}/gdcm-md5-SVNtrunk/md5main" --version)
endif()
# InstallTree tests:
#
add_test(TutorialStep5-InstallTreeTest
"${install_dir}/bin/Tutorial" 49)
if(CVS_EXECUTABLE)
add_test(KWStyle-InstallTreeTest
"${install_dir}/bin/KWStyle" -xml "${kwstyleXmlFile}" "${header}")
endif()
if(Subversion_SVN_EXECUTABLE)
add_test(gdcm-md5-InstallTreeTest
"${install_dir}/bin/md5main" --version)
endif()
Markdown is supported
0% or
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment