unset("${CMAKE_FIND_PACKAGE_NAME}_FOUND")

include(CMakeFindDependencyMacro)

find_dependency(smtk)
find_dependency(VTK COMPONENTS CommonCore CommonDataModel IOXML hdf5)
find_dependency(Boost COMPONENTS filesystem)

# Set the directory where sample data is installed.
# Compute the installation prefix relative to this file.
get_filename_component(_IMPORT_PREFIX "${CMAKE_CURRENT_LIST_FILE}" PATH)
get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
if(_IMPORT_PREFIX STREQUAL "/")
  set(_IMPORT_PREFIX "")
endif()
set(${CMAKE_FIND_PACKAGE_NAME}_DATA "${_IMPORT_PREFIX}/share/@PROJECT_NAME@/@PROJECT_VERSION@/data")

include("${CMAKE_CURRENT_LIST_DIR}/${CMAKE_FIND_PACKAGE_NAME}Targets.cmake")

include("${CMAKE_CURRENT_LIST_DIR}/AEVAVTKModules-targets.cmake")
include("${CMAKE_CURRENT_LIST_DIR}/AEVAVTKModules-vtk-module-properties.cmake")

if (@SMTK_ENABLE_PARAVIEW_SUPPORT@) # SMTK_ENABLE_PARAVIEW_SUPPORT
  include("${CMAKE_CURRENT_LIST_DIR}/AEVASessionPlugins-aeva_session_paraview_plugins-targets-depends.cmake")
  include("${CMAKE_CURRENT_LIST_DIR}/AEVASessionPlugins-targets.cmake")
  include("${CMAKE_CURRENT_LIST_DIR}/AEVASessionPlugins-paraview-plugin-properties.cmake")
endif ()

if (NOT DEFINED "${CMAKE_FIND_PACKAGE_NAME}_FOUND")
  set("${CMAKE_FIND_PACKAGE_NAME}_FOUND" 1)
endif ()
