cmake_minimum_required(VERSION 3.12)

project(LidarViewSuperBuild)
set (SuperBuild_CMAKE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/CMake")
set (SuperBuild_PROJECTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/Projects")
set (SuperBuild_BINARY_DIR ${LidarViewSuperBuild_BINARY_DIR}) # required to do FindPackage(ParaView) inside LidarView's CMakeLists

set(qt_version 5)
list(APPEND qt5_extra_options -no-icu)

macro (superbuild_setup_variables)
  include(SuperbuildVersionMacros)
  # if (paraview_SOURCE_SELECTION STREQUAL "git")
  #   # Assuming master; just use the latest version, but let the user set their
  #   # own version in case it is actually a branch from some other version.
  #   set(PARAVIEW_VERSION_DEFAULT "5.5.0"
  #     CACHE STRING "The default version of ParaView to use if it cannot be detected")
  #   mark_as_advanced(PARAVIEW_VERSION_DEFAULT)
  #   set(paraview_default_version "${PARAVIEW_VERSION_DEFAULT}")
  # elseif (paraview_SOURCE_SELECTION STREQUAL "source")
  #   # If it is a git repo, we'll get it that way, otherwise we will look at the
  #   # `version.txt` in the checkout.
  #   set(paraview_default_version "")
  # else ()
  #   # The selection is the version number; use it.
  #   set(paraview_default_version "${paraview_SOURCE_SELECTION}")
  # endif()
  # superbuild_set_version_variables(paraview "${paraview_default_version}" "paraview-version.cmake" "version.txt")
  # set(paraview_version "${paraview_version_major}.${paraview_version_minor}")
  set(paraview_version "5.6")
endmacro ()
#------------------------------------------------------------------------------
# Set a default build type if none was specified
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  # Set the possible values of build type for cmake-gui
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
    "MinSizeRel" "RelWithDebInfo")
endif()

#-----------------------------------------------------------------------------
# Collect information about the build platform.
include(CheckTypeSize)
check_type_size(void* VOID_PTR_SIZE BUILTIN_TYPES_ONLY)
if (VOID_PTR_SIZE EQUAL 8)
  set(LV_BUILD_ARCHITECTURE "64")
else ()
  set(LV_BUILD_ARCHITECTURE "32")
endif()

# Set suffix to be used for generating archives. This ensures that the package
# files have decent names that we can directly upload to the website.
set (package_suffix "${CMAKE_SYSTEM_NAME}-${LV_BUILD_ARCHITECTURE}bit")

#-----------------------------------------------------------------------------
# Setup CMAKE_MODULE_PATH so that platform specific configurations are processed
# before the generic ones.
set (CMAKE_MODULE_PATH
  "${SuperBuild_PROJECTS_DIR}"
  "${SuperBuild_CMAKE_DIR}"
  "${CMAKE_CURRENT_SOURCE_DIR}"
  "${CMAKE_CURRENT_SOURCE_DIR}/../CMake"
  ${CMAKE_MODULE_PATH})

function (superbuild_find_projects var)
  # Some of these allow using system libraries.
  set(projects
    cxx11
    paraview
    python
    python3
    qt5
    pythonqt
    boost
    bzip2
    eigen
    liblas
    freetype
    opencv
    pcap
    png
    zlib
    ceres
    glog
    pcl
    qhull
    flann
    nanoflann
    yaml
    darknet
    g2o
    )

  if (UNIX)
    list(APPEND projects
      libxml2
      ffi
    )

    if (NOT APPLE)
      list(APPEND projects
        fontconfig
        gperf
        utillinux
      )
    endif()
  endif()

  if (COMMAND add_project_to_superbuild)
    add_project_to_superbuild(projects)
  else (COMMAND add_project_to_superbuild)
	  message(WARNING "The function add_project_to_superbuild is not defined. Only LidarView's common dependencies will be compile.")
  endif(COMMAND add_project_to_superbuild)
  set("${var}"
    ${projects}
    PARENT_SCOPE)
endfunction ()


if (WIN32)
  if ( (NOT "${CMAKE_GENERATOR}" MATCHES "^NMake.*$") OR
       (NOT "${CMAKE_GENERATOR}" MATCHES "^Visual Studio.*$"))
    # not use VS environment. We need to be pointed to nmake and devenv paths
    # since they are needed when building tools (qt, python, etc.)
    find_program(DEVENV_PATH devenv)
    find_program(NMAKE_PATH nmake)
    mark_as_advanced(DEVENV_PATH NMAKE_PATH)
  endif()
endif()

if(UNIX)
  # The following variable is used to define if python libs have to be used from the system 
  # directory (USE_SYSTEM_python3=True) or shipped in install dir (USE_SYSTEM_python3=False)
  # this behavior is managed by the superbuild python install functions
  if(NOT DEFINED USE_SYSTEM_python3)
    # it is still possible to pass -DUSE_SYSTEM_python3=False to cmake
    message(STATUS "Defaulting USE_SYSTEM_python3 to True (was undefined and we are on UNIX)")
    set(USE_SYSTEM_python3 True CACHE BOOL INTERNAL)
  endif()

  # This is needed to ensure the superbuild projects to use the same python version.
  # We force python to version 3.7 as it is the only one that has been tested
  find_package(Python3 3.7 EXACT QUIET REQUIRED COMPONENTS Interpreter Development)

  # By setting the following variables we specify a python version for FindPythonLibs
  # (See cmake FindPythonLibs documentation)
  set(PYTHON_INCLUDE_DIRS ${Python3_INCLUDE_DIRS})
  set(PYTHON_INCLUDE_DIR ${Python3_INCLUDE_DIRS})
  set(PYTHON_LIBRARY ${Python3_LIBRARIES})
  
  # Python3_INCLUDE_DIR and Python3_LIBRARY are Artefacts in FindPython3
  # Both can be used to specific a python version
  # (See cmake FindPython3 documentations)
  set(Python3_INCLUDE_DIR ${Python3_INCLUDE_DIRS})
  set(Python3_LIBRARY ${Python3_LIBRARIES})
endif()

function (superbuild_add_packaging)
  if (WIN32)
    set(generators
      ZIP
      NSIS)
  elseif (APPLE)
    set(generators
      DragNDrop)
  else ()
    set(generators
      TGZ
      TXZ)
  endif ()
  list(GET generators 0 default_generator)

  if (qt5_enabled AND (USE_SYSTEM_qt5 OR APPLE OR WIN32))
    list(APPEND superbuild_export_variables
      Qt5_DIR)
    find_package(Qt5 QUIET REQUIRED COMPONENTS Core)
    set(qt5_version "${Qt5Core_VERSION_MAJOR}.${Qt5Core_VERSION_MINOR}")
  else ()
    set(qt5_version "${qt5_SOURCE_SELECTION}")
  endif ()
  list(APPEND superbuild_export_variables
    qt5_version)
  

  # pass some variables that are required for packaging step:
  list(APPEND superbuild_export_variables
    PARAVIEW_VERSION
    package_suffix
    )

  set(default_package lidarview)
  foreach (generator IN LISTS generators)
      superbuild_add_extra_package_test(lidarview "${generator}"
      LABELS  "LidarView" # does not have to be ${SOFTWARE_NAME} I think
      TIMEOUT 6400)
  endforeach ()

  if (default_package)
    superbuild_enable_install_target("${default_package}/${default_generator}")
  endif ()
endfunction ()

function (superbuild_add_tests)
  # TODO: add existing tests
  # add_subdirectory("${CMAKE_SOURCE_DIR}/tests" "${CMAKE_BINARY_DIR}/tests")
endfunction ()

# skiped module as defined in paraview superbuild.
# One difference: pythonQt needs Multimedia so we don't skip it.
set(qt5_skip_modules
  qtspeech
  qtconnectivity
  qtgamepad
  qtlocation
  qtsensors
  qtserialport
  qtwayland
  qtwebchannel
  qtwebengine
  qtwebsockets)
list(APPEND qt5_process_environment
  BUILD_IN_SOURCE 1)

set(boost_libraries
  date_time
  filesystem
  iostreams
  program_options
  thread
  chrono
  regex
  system)
set(boost_extra_options
  "-sNO_BZIP2=1")

list(APPEND superbuild_version_files
  "${CMAKE_CURRENT_LIST_DIR}/versions.cmake")
list(APPEND superbuild_project_roots
  "${SuperBuild_PROJECTS_DIR}")

set(_superbuild_default_cxx11 ON)

# set the default for qt5 to be 5.10
set(_superbuild_qt5_default_selection "5.10")

option(ENABLE_all "Enable all optional dependancy like pcl, ceres, opencv, darknet, ..." OFF)
if (ENABLE_all)
  set(ENABLE_opencv ON CACHE BOOL "enable OpenCV")
  set(ENABLE_ceres ON CACHE BOOL "enable Ceres")
  set(ENABLE_pcl ON CACHE BOOL "enable PCL")
  set(ENABLE_nanoflann ON CACHE BOOL "enable nanoflann")
  set(ENABLE_darknet ON CACHE BOOL "enable darknet")
  set(ENABLE_g2o ON CACHE BOOL "enable G2O")
endif(ENABLE_all)

option(ENABLE_slam "Build Lidar SLAM (requires PCL, Ceres, nanoflann; optional g2o)" OFF)
option(ENABLE_old_slam "Build old deprecated Lidar SLAM (requires PCL, Ceres, nanoflann). Should not be used if new SLAM is being built." OFF)
mark_as_advanced(ENABLE_old_slam)
if (ENABLE_slam AND ENABLE_old_slam)
  message(WARNING "ENABLE_slam and ENABLE_old_slam are both set to ON. "
                  "It is strongly recommended to build only one of these two SLAM filters to avoid runtime errors due to names collisions.")
endif(ENABLE_slam AND ENABLE_old_slam)

add_subdirectory(common-superbuild)

# Check if some Boost environment variables could hide local Boost install
if (NOT ${USE_SYSTEM_boost} AND (DEFINED ENV{BOOSTROOT} OR DEFINED ENV{BOOST_ROOT} OR DEFINED ENV{BOOST_LIBRARYDIR} OR DEFINED ENV{BOOST_INCLUDEDIR}))
  message(WARNING "Some Boost environment variables are set and may hide the local superbuild Boost installation. "
                  "Consider enabling USE_SYSTEM_boost flag or unsetting the following environement variables :\n"
                  " BOOSTROOT=$ENV{BOOSTROOT}\n BOOST_ROOT=$ENV{BOOST_ROOT}\n BOOST_LIBRARYDIR=$ENV{BOOST_LIBRARYDIR}\n BOOST_INCLUDEDIR=$ENV{BOOST_INCLUDEDIR}")
endif()